Sample project screenshot. Windows 7

NB #2 All manipulatations with taskbar buttons must be done after button will be created, to catch this moment we should subscribe to WM_TASKBARBUTTONCREATED event, that must firstly registered by RegisterWindowMessage(‘TaskbarButtonCreated’); – I reccomend you to add this registration to initialization section of unit with your form:

//.....//
initialization
  WM_TASKBARBUTTONCREATED := RegisterWindowMessage('TaskbarButtonCreated');
end.

NB #3 You must be sure that Application.MainFormOnTaskbar is True; or drop on form TLMDFormVista for delphi 6-2005 versions

Now, when we registered message we can handle it in WndProc method to setup taskbar button:

type
  TForm8 = class(TForm)
    Timer1: TTimer;
    ImageList1: TImageList;
    ProgressBar1: TProgressBar;
    procedure FormCreate(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    FTick: Int64;
    FButtons: array[0..2] of TThumbButton;
    FNormalIcon: Cardinal;
    FPauseIcon: Cardinal;
    FTaskBar: ITaskbarList3;
  protected
    procedure WndProc(var Message: TMessage); override;
    { Private declarations }
  public
    { Public declarations }
  end;
//...//
procedure TForm8.WndProc(var Message: TMessage);
begin
  inherited;
  // Is tasbar button created?
  if Message.Msg = WM_TASKBARBUTTONCREATED then
  begin
    // Create instance of ITaskbarList3
    CoCreateInstance(CLSID_TaskbarList, nil, CLSCTX_INPROC_SERVER, IID_ITaskbarList3, FTaskBar);
    // Init
    FTaskBar.HrInit;
    // This method set progress state of tasbar button.
    // Button has next states: error, paused, normal and indetermintate
    FTaskBar.SetProgressState(Handle, TBPF_NORMAL);
    FNormalIcon := LoadIcon(0, IDI_ASTERISK);
    FPauseIcon := LoadIcon(0, IDI_WARNING);
    // Set overlay icon for taskbar button - "!" - asterix
    FTaskBar.SetOverlayIcon(Handle, FNormalIcon, 'In progress');

    // Buttons setup
    // Set imagelist handle that contains glyphs for our buttons
    FTaskBar.ThumbBarSetImageList(Handle, ImageList1.Handle);
    // This identificator will be used to determinate what button pressed
    FButtons[0].iId := 40001;
    FButtons[0].dwFlags := THBF_ENABLED;
    FButtons[0].iBitmap := 0;
    StringToWideChar('Reset', FButtons[0].szTip, 260);
    FButtons[0].dwMask := THB_BITMAP or THB_FLAGS or THB_TOOLTIP;

    FButtons[1].iId := 40002;
    FButtons[1].dwFlags := THBF_DISABLED;
    FButtons[1].iBitmap := 1;
    StringToWideChar('Play', FButtons[1].szTip, 260);
    FButtons[1].dwMask := THB_BITMAP or THB_FLAGS or THB_TOOLTIP;

    FButtons[2].iId := 40003;
    FButtons[2].dwFlags := THBF_ENABLED;
    FButtons[2].iBitmap := 2;
    StringToWideChar('Pause', FButtons[2].szTip, 260);
    FButtons[2].dwMask := THB_BITMAP or THB_FLAGS or THB_TOOLTIP;
    // Add buttons to thumbnail
    FTaskBar.ThumbBarAddButtons(Handle, 3, @FButtons[0]);
    FTaskBar.SetThumbnailTooltip(Handle, 'Test');
    Timer1.Enabled := True;
  end;
end;

To handle buttons click we need to catch WM_COMMAND message, WParamLo field will contains id of clicked button:

procedure TForm8.WndProc(var Message: TMessage);
begin
  //...//
  if Message.Msg = WM_COMMAND then
  begin
    // Handle 'Reset' button
    if Message.WParamLo = 40001 then
    begin
      Timer1.Enabled := True;
      FTaskBar.SetProgressState(Handle, TBPF_NORMAL);
      FTick := 0;
    end;
    // Handle 'Play' button
    if Message.WParamLo = 40002 then
    begin
      // Run timer again
      Timer1.Enabled := True;
      FTaskBar.SetProgressState(Handle, TBPF_NORMAL);
      // Set overlay icon to asterix icon
      FTaskBar.SetOverlayIcon(Handle, FNormalIcon, 'In progress');
      ProgressBar1.State := pbsNormal;
      // Disable 'Play' button
      FButtons[1].dwFlags := THBF_DISABLED;
      // Enable 'Pause' button
      FButtons[2].dwFlags := THBF_ENABLED;
      // Update buttons
      FTaskBar.ThumbBarUpdateButtons(Handle, 3, @FButtons[0])
    end;
    // Handle 'Pause' button. Almost the same as for 'Play'
    if Message.WParamLo = 40003 then
    begin
      Timer1.Enabled := False;
      FTaskBar.SetProgressState(Handle, TBPF_PAUSED);
      FTaskBar.SetOverlayIcon(Handle, FPauseIcon, 'Paused');
      ProgressBar1.State := pbsPaused;
      FButtons[1].dwFlags := THBF_ENABLED;
      FButtons[2].dwFlags := THBF_DISABLED;
      FTaskBar.ThumbBarUpdateButtons(Handle, 3, @FButtons[0])
    end;
  end;
end;

And finally OnTimer handler code:

procedure TForm8.Timer1Timer(Sender: TObject);
begin
  FTaskBar.SetProgressValue(Handle, FTick, 200);
  ProgressBar1.Position := FTick;
  Inc(FTick);
  // It's all?
  if FTick >= 200 then
  begin
    // Set indeterminate progress mode for tasbar button
    FTaskBar.SetProgressState(Handle, TBPF_INDETERMINATE);
    Timer1.Enabled := False;
  end;
end;

That’s all for “Part 1″ – I hope that it will be useful for someone.

procedure TForm1.LMDMaskEdit1UserRule(Sender: TObject; var Ok: Boolean;
   c: WideChar; at: Integer);
begin
  ok := ( c = 'a' ) or ( c = 'b' );
end;

While implementing some kind of tricky user rule, it is very easy to yield to temptation of changing text with OnUserRule event.
This is what should never be done unless you have some free hours to debug unexpected behavior of your construction.

So, the message of this post is: do not use the OnUserRule event for changing the Text while it is being checked.
You should use the OnTextChangedAt for this purposes.

Here is an example of how to modify text while user is entering characters: LMDMaskEdit control with a custom rule ( Mask = ‘rr’ ) that allows entry of 2-digit numbers between 00 and 23 (including bounds). If a number is greater than 23 is entered, then the units digit is automatically set to 3.

procedure TForm1.LMDMaskEdit1UserRule(Sender: TObject; var Ok: Boolean;
   c: WideChar; at: Integer);
begin
  case at of
    1: ok := ( Pos(AnsiChar(c), '012' ) > 0);
    2: ok := ( (Pos(AnsiChar(LMDMaskEdit1.Text[1]), '012' )
         > 0) ) and
        ( (Pos(AnsiChar(c), '0123456789' ) > 0) ) ;
  end;
end;

procedure TForm1.LMDMaskEdit1TextChangedAt(sender: TObject; At: Integer);
begin
  if (at = 2) and (Pos(LMDMaskEdit1.BlankChar,
    LMDMaskEdit1.Text) = 0) then
    if strtoint(LMDMaskEdit1.Text) > 23 then
      LMDMaskEdit1.Text := '23';
end;

Note that LMDMaskEdit1.TextChangedAt can be simplified in this example if
BlankChar = ’0′:

procedure TForm1.LMDMaskEdit1TextChangedAt(sender: TObject; At: Integer);
begin
  if (at = 2)  then
    if strtoint(LMDMaskEdit1.Text) > 23 then
      LMDMaskEdit1.Text := '23';
end;

Improved look of TLMDCalendar

Yes – it’s still well known TLMDCalendar, and here is the DFM snippet of it:

object LMDCalendar1: TLMDCalendar
  Left = 48
  Top = 87
  Width = 234
  Height = 225
  BackFX.AlphaBlend.FillObject.Style = sfGradient
  BackFX.AlphaBlend.FillObject.AlphaLevel = 255
  BackFX.FlipHorizontal = True
  BackFX.Buffered = True
  Bevel.BorderColor = clGradientActiveCaption
  Bevel.Mode = bmStandard
  Bevel.StandardStyle = lsNone
  CellStyle.Font.Charset = DEFAULT_CHARSET
  CellStyle.Font.Color = 5392449
  CellStyle.Font.Height = -11
  CellStyle.Font.Name = 'Tahoma'
  CellStyle.Font.Style = [fsBold]
  CellStyle.Font3D.LightColor = clSilver
  CellStyle.Font3D.ShadowColor = clGradientActiveCaption
  CellStyle.Font3D.Style = tdSunken
  CellStyle.Bevel.StyleInner = bvShadow
  CellStyle.Bevel.StyleOuter = bvShadow
  CellStyle.Bevel.Mode = bmCustom
  CellStyle.FillObject.Style = sfBrush
  CellStyle.FillObject.AlphaLevel = 255
  CellStyle.FillObject.Brush.Color = 13814989
  Date = 40115.000000000000000000
  Day = 29
  DayCaptionCellStyle.Font.Charset = DEFAULT_CHARSET
  DayCaptionCellStyle.Font.Color = clGray
  DayCaptionCellStyle.Font.Height = -11
  DayCaptionCellStyle.Font.Name = 'Tahoma'
  DayCaptionCellStyle.Font.Style = [fsBold]
  DayCaptionCellStyle.Bevel.StyleOuter = bvLowered
  DayCaptionCellStyle.Bevel.Mode = bmStandard
  DayCaptionCellStyle.Bevel.StandardStyle = lsNone
  DayCaptionCellStyle.FillObject.Style = sfBrush
  DayCaptionCellStyle.FillObject.AlphaLevel = 255
  DayCaptionCellStyle.FillObject.Brush.Color = cl3DLight
  FillObject.AlphaLevel = 255
  FillObject.Brush.Color = clMoneyGreen
  GridPen.Color = clSilver
  GridPen.Style = psClear
  GridPen.Width = 0
  Header.Style.Font.Charset = DEFAULT_CHARSET
  Header.Style.Font.Color = 5392449
  Header.Style.Font.Height = -11
  Header.Style.Font.Name = 'Tahoma'
  Header.Style.Font.Style = [fsBold]
  Header.Style.Font3D.Style = tdSunken
  Header.Style.Bevel.EdgeStyle = etBump
  Header.Style.Bevel.Mode = bmStandard
  Header.Style.Bevel.StandardStyle = lsRaised
  Header.Style.FillObject.Style = sfGradient
  Header.Style.FillObject.Gradient.Color = 16119285
  Header.Style.FillObject.Gradient.ColorCount = 32
  Header.Style.FillObject.Gradient.EndColor = 12697020
  Header.Style.FillObject.AlphaLevel = 255
  Header.Elements = [heMonthName, heMonthBtns, heYear]
  Header.ButtonStyle = ubsOfficeTransp
  Header.ButtonFont.Charset = DEFAULT_CHARSET
  Header.ButtonFont.Color = clWindowText
  Header.ButtonFont.Height = -11
  Header.ButtonFont.Name = 'Tahoma'
  Header.ButtonFont.Style = []
  Header.MinHeight = 22
  Header.MonthName.Alignment = taCenter
  Header.MonthName.Order = 0
  Header.YearValue.Alignment = taCenter
  Header.YearValue.Order = 0
  Header.MonthUp.Alignment = taRightJustify
  Header.MonthUp.Order = 15
  Header.MonthDn.Alignment = taLeftJustify
  Header.MonthDn.Order = -15
  Header.YearUp.Alignment = taRightJustify
  Header.YearUp.Order = 20
  Header.YearDn.Alignment = taLeftJustify
  Header.YearDn.Order = -20
  Header.MonthCombo.Alignment = taLeftJustify
  Header.MonthCombo.Order = 0
  Header.YearCombo.Alignment = taLeftJustify
  Header.YearCombo.Order = 0
  Header.Today.Alignment = taLeftJustify
  Header.Today.Order = 0
  MarkedCellStyle.Font.Charset = DEFAULT_CHARSET
  MarkedCellStyle.Font.Color = clWindowText
  MarkedCellStyle.Font.Height = -11
  MarkedCellStyle.Font.Name = 'Tahoma'
  MarkedCellStyle.Font.Style = []
  MarkedCellStyle.Bevel.Mode = bmCustom
  MarkedCellStyle.FillObject.Style = sfBrush
  MarkedCellStyle.FillObject.AlphaLevel = 255
  MarkedCellStyle.FillObject.Brush.Color = clActiveCaption
  Marked2CellStyle.Font.Charset = DEFAULT_CHARSET
  Marked2CellStyle.Font.Color = clWindowText
  Marked2CellStyle.Font.Height = -11
  Marked2CellStyle.Font.Name = 'Tahoma'
  Marked2CellStyle.Font.Style = []
  Marked2CellStyle.Bevel.Mode = bmCustom
  Marked2CellStyle.FillObject.AlphaLevel = 255
  Month = 10
  SelectedCellStyle.Font.Charset = DEFAULT_CHARSET
  SelectedCellStyle.Font.Color = clWhite
  SelectedCellStyle.Font.Height = -11
  SelectedCellStyle.Font.Name = 'Tahoma'
  SelectedCellStyle.Font.Style = [fsBold]
  SelectedCellStyle.Font3D.ShadowColor = clBlack
  SelectedCellStyle.Font3D.Style = tdShadow
  SelectedCellStyle.Bevel.StyleInner = bvLowered
  SelectedCellStyle.Bevel.StyleOuter = bvNormal
  SelectedCellStyle.Bevel.BorderColor = clGray
  SelectedCellStyle.Bevel.BorderWidth = 1
  SelectedCellStyle.Bevel.LightColor = 15647132
  SelectedCellStyle.Bevel.Mode = bmCustom
  SelectedCellStyle.Bevel.ShadowColor = 15647132
  SelectedCellStyle.FillObject.Style = sfGradient
  SelectedCellStyle.FillObject.Gradient.ColorCount = 100
  SelectedCellStyle.FillObject.Gradient.TwoColors = False
  SelectedCellStyle.FillObject.Gradient.ColorList = (
    15905663
    15568171
    14315781
    14315781)
  SelectedCellStyle.FillObject.AlphaLevel = 255
  SelectedCellStyle.FillObject.Brush.Color = clSkyBlue
  ShowDayHint = True
  SpecialDates = <
    item
      Style.Font.Charset = DEFAULT_CHARSET
      Style.Font.Color = clWhite
      Style.Font.Height = -11
      Style.Font.Name = 'Tahoma'
      Style.Font.Style = [fsBold]
      Style.Font3D.ShadowColor = clBlack
      Style.Font3D.Style = tdShadow
      Style.Bevel.StyleInner = bvLowered
      Style.Bevel.StyleOuter = bvLowered
      Style.Bevel.LightColor = 9597787
      Style.Bevel.Mode = bmCustom
      Style.Bevel.ShadowColor = 6509379
      Style.FillObject.Style = sfBrush
      Style.FillObject.AlphaLevel = 255
      Style.FillObject.Brush.Color = 11045750
      Caption = '345345'
      Index = 0
      DisplayName = 'TLMDSpecialDates'
      FDates = (
        40100.681377314820000000
        '557y6')
    end>
  StartDay = 2
  StartWithActualDate = True
  TabOrder = 1
  Year = 2009
end

Just copy it to clipboard and insert on your form.

PS. If you have access to SVN you can add the follwoing 2 strings into the OnCreate event of Form (they paint the non active days of previous or next month):

  LMDCalendar1.InactiveCellStyle := LMDCalendar1.CellStyle;
  LMDCalendar1.InactiveCellStyle.Font.Color := RGB(155, 157, 162);

So how can a programmer use described features? Possibilities are endless:

1. Download a filelist and get a specified file from zip file only
2. Multi-threaded file downloads
3. Allow end-users to pause/resume downloads of large files

Here is simple code to implement first example (downloading a specified file from zip):

  LMDWebHTTPGet1.URL := 'http://www.lmd.de/downloads/lmd2010vcl/setupse10d14.zip';
  // "end of central directory" size.
  // Minus shows that we read it from end of file
  LMDWebHTTPGet1.RangeEnd := -17;
  // Downloads last 17 bytes of file
  if LMDWebHTTPGet1.Process(False, False) then
  begin
    LEndOfCentralRecord.LoadFromStream(LMDWebHTTPGet1.Data);
    // Fills RangeStart by "Central Directory" structure begin offset
    LMDWebHTTPGet1.RangeStart := LEndOfCentralRecord.OffsetOfCentralDirectory;
    LMDWebHTTPGet1.RangeEnd := LMDWeHTTPGet1.RangeStart + LEndOfCentralRecord.SizeOfCentralDirectory;
    // Downloads "Central Directory" structure
    if LMDWebHTTPGet1.Process(False, False) then
    begin
      LCentralDirectory.LoadFromStream(LMDWebHTTPGet1.Data);
      // Fills RangeStart by offset of compressed file in ZIP
      LMDWebHTTPGet1.RangeStart := LCentralDirectory.Files['readme.txt'].FileOffset;
      // Compressed size
      LMDWebHTTPGet1.RangeEnd := LMDWebHTTPGet1.RangeStart + LCentralDirectory.Files['readme.txt'].CompressedSize;
      // Downloads compressed file "readme.txt"
      if LMDWebHTTPGet1.Process(False, False) then
      begin
        // Processing of compressed file
      end;
    end;
  end;

LEndOfCentralRecord, LCentralDirectory are placeholders that schematically shows corresponding zip format structures – “Central directory structure” and “End of central directory record”. The full specification is described here.

Besides that WebPack includes a demo project in demos\lmdweb\LMDWebHTTPGetResume folder.